1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
|
# Copyright 2019 Hubert Chathi <hubert@uhoreg.ca>
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
defmodule Polyjuice.Client do
@moduledoc """
Matrix client functions.
"""
require Logger
@type t :: %__MODULE__{
base_url: String.t(),
access_token: String.t()
}
@enforce_keys [:base_url]
defstruct [
:base_url,
:access_token,
:user_id,
:storage
]
@doc "The r0 client URL prefix"
def prefix_r0, do: "/_matrix/client/r0"
@doc "The unstable client URL prefix"
def prefix_unstable, do: "/_matrix/client/unstable"
defprotocol API do
@moduledoc """
Protocol for calling the Matrix client API.
"""
@doc """
Call a Matrix client API. This is a lower-level function; generally, clients
will want to call one of the higher-level functions from `Polyjuice.Client`.
"""
@spec call(
client_api :: Polyjuice.Client.API.t(),
endpoint :: Polyjuice.Client.Endpoint.Proto.t()
) :: Any
def call(client_api, endpoint)
@doc """
Generate a unique transaction ID.
"""
@spec transaction_id(client_api :: Polyjuice.Client.API.t()) :: String.t()
def transaction_id(client_api)
@doc """
Get the child spec for the sync process.
"""
@spec sync_child_spec(
client_api :: Polyjuice.Client.API.t(),
listener :: pid() | fun(),
opts :: list()
) :: map()
def sync_child_spec(client_api, listener, opts \\ [])
end
defimpl Polyjuice.Client.API do
def call(%{base_url: base_url, access_token: access_token}, endpoint) do
%Polyjuice.Client.Endpoint.HttpSpec{
method: method,
headers: headers,
url: url,
body: body,
transform: transform,
auth_required: auth_required
} = Polyjuice.Client.Endpoint.Proto.http_spec(endpoint, base_url)
Logger.debug("calling #{url}")
if auth_required and access_token == nil do
{:error, :auth_required}
else
{:ok, status_code, resp_headers, body} =
:hackney.request(
method,
url,
if access_token do
[{"Authorization", "Bearer #{access_token}"} | headers]
else
headers
end,
body,
[:with_body]
)
Logger.debug("status code #{status_code}")
transform.(status_code, resp_headers, body)
end
end
def transaction_id(_) do
"#{Node.self()}_#{:erlang.system_time(:millisecond)}_#{:erlang.unique_integer()}"
end
def sync_child_spec(client, listener, opts \\ []) do
Polyjuice.Client.Sync.child_spec([client, listener | opts])
end
end
@doc """
Send a message to a room.
`msg` can either be anything that implements the
`Polyjuice.Client.MsgBuilder.MsgData` protocol (which will be sent as an
`m.message`), or a map (which specifies the full message content).
Examples:
Polyjuice.Client.send_message(client, "text message", "!room_id")
Polyjuice.Client.send_message(
client,
{"message with formatting", "<i>message</i> with <b>formatting</b>"},
"!room_id"
)
Polyjuice.Client.send_message(
client,
["Hello, ", Polyjuice.Client.MsgBuilder.mention("@world:example.com")],
"!room_id"
)
Polyjuice.Client.send_message(
client,
%{"msgtype" => "m.notice", "body" => "using full message content"},
"!room_id"
)
"""
@spec send_message(
client_api :: Polyjuice.Client.API.t(),
msg :: map | Polyjuice.Client.MsgBuilder.MsgData.t(),
room :: String.t()
) :: String.t()
def send_message(client_api, msg, room) when is_binary(room) do
cond do
Polyjuice.Client.MsgBuilder.MsgData.impl_for(msg) != nil ->
Polyjuice.Client.API.call(
client_api,
%Polyjuice.Client.Endpoint.PutRoomsSend{
txn_id: Polyjuice.Client.API.transaction_id(client_api),
room: room,
event_type: "m.room.message",
message: Polyjuice.Client.MsgBuilder.to_message(msg)
}
)
is_map(msg) and not Map.has_key?(msg, :__struct__) ->
Polyjuice.Client.API.call(
client_api,
%Polyjuice.Client.Endpoint.PutRoomsSend{
txn_id: Polyjuice.Client.API.transaction_id(client_api),
room: room,
event_type: "m.room.message",
message: msg
}
)
true ->
raise ArgumentError, message: "invalid argument msg"
end
end
@doc """
Send an event to a room.
"""
@spec send_event(
client_api :: Polyjuice.Client.API.t(),
event_type :: String.t(),
event :: map,
room :: String.t()
) :: String.t()
def send_event(client_api, event_type, event, room)
when is_binary(event_type) and is_map(event) and is_binary(room) do
Polyjuice.Client.API.call(
client_api,
%Polyjuice.Client.Endpoint.PutRoomsSend{
txn_id: Polyjuice.Client.API.transaction_id(client_api),
room: room,
event_type: event_type,
message: event
}
)
end
@doc """
Update the client's read receipt (of the given type) to the given message in the
given room.
"""
@spec update_read_receipt(
client_api :: Polyjuice.Client.API.t(),
room :: String.t(),
event_id :: String.t(),
receipt_type :: String.t()
) :: Any
def update_read_receipt(client_api, room, event_id, receipt_type \\ "m.read")
when is_binary(room) and is_binary(event_id) and is_binary(receipt_type) do
Polyjuice.Client.API.call(
client_api,
%Polyjuice.Client.Endpoint.PostRoomsReceipt{
room: room,
event_id: event_id,
receipt_type: receipt_type
}
)
end
end
|
