defmodule LSGWeb.IrcController do
  use LSGWeb, :controller

  plug LSGWeb.ContextPlug

  def index(conn, params) do
    network = Map.get(params, "network")
    channel = if c = Map.get(params, "channel"), do: LSGWeb.reformat_chan(c)
    commands = for mod <- ([IRC.Account.AccountPlugin] ++ Application.get_env(:lsg, :irc)[:plugins] ++ Application.get_env(:lsg, :irc)[:handlers]) do
      identifier = Module.split(mod) |> List.last |> String.replace("Plugin", "") |> Macro.underscore
      {identifier, mod.irc_doc()}
    end
    |> Enum.reject(fn({_, i}) -> i == nil end)
    members = cond do
      network -> IRC.Membership.expanded_members_or_friends(conn.assigns.account, network, channel)
      true -> IRC.Membership.of_account(conn.assigns.account)
    end
    render conn, "index.html", network: network, commands: commands, channel: channel, members: members
  end

  def txt(conn, %{"name" => name}) do
    case String.split(name, ".", parts: 2) do
      [name, "txt"] ->
        data = data()
        if Map.has_key?(data, name) do
          lines = Enum.join(data[name], "\n")
          text(conn, lines)
        else
          conn
          |> put_status(404)
          |> text("Not found")
        end
      _ ->
        do_txt(conn, name)
    end
  end
  def txt(conn, _), do: do_txt(conn, nil)


  defp do_txt(conn, nil) do
    doc = LSG.IRC.TxtPlugin.irc_doc()
    data = data()
    lines = Enum.reduce(data, 0, fn({_, lines}, acc) -> acc + Enum.count(lines) end)
    conn
    |> assign(:title, "txt")
    |> render("txts.html", data: data, doc: doc, files: Enum.count(data), lines: lines)
  end

  defp do_txt(conn, txt) do
    data = data()
    base_url = cond do
      conn.assigns[:chan] -> "/#{conn.assigns.network}/#{LSGWeb.format_chan(conn.assigns.chan)}"
      true -> "/-"
    end
    if lines = Map.get(data, txt) do
      lines = Enum.map(lines, fn(line) ->
        line
        |> String.split("\\\\")
        |> Enum.intersperse(Phoenix.HTML.Tag.tag(:br))
      end)
      conn
      |> assign(:breadcrumbs, [{"txt", "#{base_url}/txt"}])
      |> assign(:title, "#{txt}.txt")
      |> render("txt.html", name: txt, data: lines, doc: nil)
    else
      conn
      |> put_status(404)
      |> text("Not found")
    end
  end

  defp data() do
    dir = Application.get_env(:lsg, :data_path) <> "/irc.txt/"
    Path.wildcard(dir <> "/*.txt")
    |> Enum.reduce(%{}, fn(path, m) ->
      path = String.split(path, "/")
      file = List.last(path)
      [key, "txt"] = String.split(file, ".", parts: 2)
      data = dir <> file
      |> File.read!
      |> String.split("\n")
      |> Enum.reject(fn(line) ->
        cond do
          line == "" -> true
          !line -> true
          true -> false
        end
      end)
      Map.put(m, key, data)
    end)
    |> Enum.sort
    |> Enum.into(Map.new)
  end

end