path: root/lib/lsg_irc/say_plugin.ex

defmodule LSG.IRC.SayPlugin do

  def irc_doc do
    """
    # say

    Say something...

    * **!say `<channel>` `<text>`** say something on `channel`
    * **!asay `<channel>` `<text>`** same but anonymously

    You must be a member of the channel.
    """
  end

  def start_link() do
    GenServer.start_link(__MODULE__, [], name: __MODULE__)
  end

  def init([]) do
    regopts = [type: __MODULE__]
    {:ok, _} = Registry.register(IRC.PubSub, "trigger:say", regopts)
    {:ok, _} = Registry.register(IRC.PubSub, "trigger:asay", regopts)
    {:ok, _} = Registry.register(IRC.PubSub, "message:private", regopts)
    {:ok, nil}
  end

  def handle_info({:irc, :trigger, "say", m = %{trigger: %{type: :bang, args: [target | text]}}}, state) do
    text = Enum.join(text, " ")
    say_for(m.account, target, text, true)
    {:noreply, state}
   end

  def handle_info({:irc, :trigger, "asay", m = %{trigger: %{type: :bang, args: [target | text]}}}, state) do
    text = Enum.join(text, " ")
    say_for(m.account, target, text, false)
    {:noreply, state}
   end

  def handle_info({:irc, :text, m = %{text: "say "<>rest}}, state) do
    case String.split(rest, " ", parts: 2) do
      [target, text] -> say_for(m.account, target, text, true)
      _ -> nil
    end
    {:noreply, state}
  end

  def handle_info({:irc, :text, m = %{text: "asay "<>rest}}, state) do
    case String.split(rest, " ", parts: 2) do
      [target, text] -> say_for(m.account, target, text, false)
      _ -> nil
    end
    {:noreply, state}
  end

  def handle_info(_, state) do
    {:noreply, state}
  end

  defp say_for(account, target, text, with_nick?) do
    for {net, chan} <- IRC.Membership.of_account(account) do
      chan2 = String.replace(chan, "#", "")
      if (target == "#{net}/#{chan}" || target == "#{net}/#{chan2}" || target == chan || target == chan2) do
        user = IRC.UserTrack.find_by_account(net, account)
        nick = if(user, do: user.nick, else: account.name)
        prefix = if(with_nick?, do: "<#{nick}> ", else: "")
        IRC.Connection.broadcast_message(net, chan, "#{prefix}#{text}")
      end
    end
  end

end